エクセルの１つのセル内の重複データを削除したい

Question

エクセルの１つのセル内にある重複データを１つだけ残し、残りを削除したいのですが、計算式がわからないので教えて頂けますでしょうか。

例：Ａ２セル内に
1234 5678 9123 1234 2345
というデータがあった場合に、
1234が重複しているので、
1234 5678 9123 2345
にしたいのですが、計算式でできますでしょうか。

それが可能でしたら、計算式を教えて頂きたいです。

以上、よろしくお願いいたします。

Answer

ECマスターズの星です。

> エクセルの１つのセル内にある重複データを１つだけ残し、残りを削除したい

詳しい者に確認いたしましたところ、
Excel関数で同じセル内の重複データを削除する関数は存在しないため、
VBAなどを利用してマクロの作成が必要ということでした。

Answer

ご回答ありがとうございます。
計算式ではさすがに無理ですか。。。

Sub test()  'この行から
    Dim i As Long
    Dim k As Long
    Dim tmp As Variant
    Dim myArray As Variant
    Application.ScreenUpdating = False
    Columns(2).ClearContents
    For i = 1 To Cells(Rows.Count, 1).End(xlUp).Row
    tmp = WorksheetFunction.Substitute(Cells(i, 1), "　", " ")
    If InStr(tmp, " ") > 0 Then
        myArray = Split(tmp, " ")
        For k = 0 To UBound(myArray)
            If InStr(Cells(i, 2), myArray(k)) = 0 Then
                Cells(i, 2) = Cells(i, 2) & myArray(k) & " "
            End If
        Next k
    Else
        Cells(i, 2) = Cells(i, 1)
    End If
    Next i
    Application.ScreenUpdating = True
End Sub 'この行まで

なんとか、希望の形になりました。
ありがとうございました。

Answer

ECマスターズの山岡です。

以下のような感じで、dictionaryを使う方法もございます。
比較部分は、instr ですと、123　という文字があった場合、
処理されない場合もあるため、Existsを使っています。
出力は、join を使うことで配列を文字列化しております。

Sub test()
    Dim i As Long
    Dim k As Long
    Dim tmp As Variant
    Dim myArray As Variant
    
    Dim dictionary   As Object
    Set dictionary = CreateObject("scripting.dictionary")
    
    Application.ScreenUpdating = False
    
    Columns(2).ClearContents
    For i = 1 To Cells(Rows.Count, 1).End(xlUp).Row
    
        tmp = WorksheetFunction.Substitute(Cells(i, 1), "　", " ")
       
        If InStr(tmp, " ") > 0 Then
            myArray = Split(tmp, " ")
            For k = 0 To UBound(myArray)
            
                If Not dictionary.Exists(myArray(k)) Then
                    dictionary.Add myArray(k), myArray(k)
                End If
        
            Next k
            Cells(i, 2) = Join(dictionary.Keys)
        Else
            Cells(i, 2) = Cells(i, 1)
        End If
        
    Next i
    Application.ScreenUpdating = True
    
End Sub