エクセルで特定の文字列を含む表示指定を複数指定したいです。

Question

いつもお世話になっております。

画像の1枚目に、楽天の受注csvを貼り付けて
別シート（2枚目の画像）に、

項目選択内に
・"樹脂ピアス"が含まれている場合は"樹脂ピアス"と表示
・"イヤリング"が含まれている場合は"イヤリング"と表示

と、複数指定したいのですが
関数がよくわからないので教えてください
（そもそもCOUNTIFが適切なのかもわかりません）

目的は、発送品準備リストを自動で表にしたいです！
よろしくお願い致します★###HR######IMG0891a77f68de3c2d9cf96458ec8a75584.jpegIMG0### ###IMG1a5366c58c20a9f46eb2ebab7427295f5.jpegIMG1###

Answer

ECマスターズの伊藤です。

> ・"樹脂ピアス"が含まれている場合は"樹脂ピアス"と表示
> ・"イヤリング"が含まれている場合は"イヤリング"と表示

> と、複数指定したいのですが
> 関数がよくわからないので教えてください

ご指定頂いた内容で、複数指定する場合は、&でif関数をつないでいただくと
ご希望の表現が可能となっております。

例えば、A1に　樹脂ピアスを含む文字列 のエクセルデータをご用意いただいた場合、
関数は下記の通りとなります。

＝＝＝＝＝＝＝＝＝＝
=if(countif(A1,"*樹脂ピアス*"),"樹脂ピアス","")&if(countif(A1,"*イヤリング*"),"イヤリング","")
＝＝＝＝＝＝＝＝＝＝

注意点としまして、例えば「樹脂ピアス」と「ピアス」が存在した場合、関数は
＝＝＝＝＝＝＝＝＝＝
=if(countif(A1,"*樹脂ピアス*"),"樹脂ピアス","")&if(countif(A1,"*ピアス*"),"ピアス","")
＝＝＝＝＝＝＝＝＝＝
となりますが、「樹脂ピアス」と「ピアス」両方の単語を含んでいるため
樹脂ピアスピアス
となっていまします。

そのため、重複する単語がある場合は、入れ子で表現していただくようになります。

重複する単語がない場合は、&でつないでいただいたほうが、管理がしやすいため
こちらの関数をご利用されることをおすすめいたします。

Answer

伊藤さんありがとうございます☆

重複するものは沢山あって、

・合金ピアス
・樹脂ピアス
・合金ネジ式イヤリング
・合金クリップ式イヤリング
・ノンホール樹脂イヤリング
・チタンピアス
・【K16GP】ピアス
・【K16GP】樹脂ピアス
・【K16GP】クリップ式イヤリング
・【K16GP】ネジ式イヤリング
・キーホルダー
・バックチャーム
・ストラップ
・ネックレス
・イヤーカフ
・【K14GF】ピアス

ぐらいかな・・・あるんですが(たぶんまだ出てきそう)、
実は昨日FBでぼやいたら、入れ子のやり方教えて頂いたのですが、ちょっと種類多すぎてcountifが適切ではないかもと言われました＞＜
他に何か良さそうな関数ってありますでしょうか？

Answer

ちなみにこうゆう表を、ダウンロードしたcsvを張り付けたら、自動で作ってくれる
が、最終目標着地です！###HR######IMG0aba79c60ac592f52eece0fc054828eee.jpegIMG0######BR###

Answer

ECマスターズの伊藤です。

項目のご確認ありがとうございました。

> 重複するものは沢山あって、

とのことですが、説明が悪く、誤解をさせてしまい申し訳ありません。

例えば、今回頂いた一覧ですと
・樹脂ピアス
・【K16GP】樹脂ピアス
が、「樹脂ピアス」で検索をすると、両方ともひっかかってしまうため、重複にあたります。

1点確認をさせていただきたいのですが、
・樹脂ピアス
・【K16GP】樹脂ピアス
は、「項目・選択肢」に、上記の文言が含まれている場合、
・樹脂ピアス
・【K16GP】樹脂ピアス
を表示させたい、ということでしょうか。

・樹脂ピアス
のみですと、ご希望の動作と異なりますでしょうか。

お手数おかけいたしますが、ご確認いただきますよう、お願いいたします。

Answer

ありがとうございます！

はい、制作時パーツを間違えてしまいそうなので、
・樹脂ピアスは樹脂ピアス
・【K16GP】樹脂ピアスは【K16GP】樹脂ピアス
と、表示させたいです！

Answer

ECマスターズの伊藤です。

> はい、制作時パーツを間違えてしまいそうなので、
> ・樹脂ピアスは樹脂ピアス
> ・【K16GP】樹脂ピアスは【K16GP】樹脂ピアス
> と、表示させたいです！

ご確認いただきまして、ありがとうございました。

ご希望の条件での絞り込みになりますと、やはりご連絡しておりました方法になります。
個数が多いと、どうしても複雑になってしまいますが、
「条件に合う文字列を含む」をエクセルの関数で表現するには
COUNTIFを利用することになります。

また、IF関数を入れ子にしていく方法ですが、こちらの方法ですと
入れ子の数に上限があり、今後、項目が増えていった場合に、利用できなくなる可能性がございます。

また、追加のしやすさもございますので、
先にご提案しております、&で記述いただくのが最適だと思います。
==========
=if(countif(A1,"*樹脂ピアス*"),"樹脂ピアス","")&if(countif(A1,"*イヤリング*"),"イヤリング","")
==========

注意点としまして、
例えばA1に「〜〜〜〜【K16GP】樹脂ピアス〜〜〜〜〜」といった文字列があった場合
==========
=if(countif(A1,"*樹脂ピアス*"),"樹脂ピアス","")&if(countif(A1,"*【K16GP】樹脂ピアス*"),"【K16GP】樹脂ピアス","")
==========
の関数ですと、結果が
樹脂ピアス【K16GP】樹脂ピアス
となってしまいます。
A1に、「【K16GP】樹脂ピアス」に「樹脂ピアス」が含まれるため、両方の結果を表示するためです。

そのため、
「樹脂ピアス」を含む　かつ　「【K16GP】樹脂ピアス」　を含まない
という関数が必要となります。
複数条件を指定するためには、COUNTIFS（※Sがつきます）という関数を利用します。
"*○○*"　と書くと　「〇〇を含まない」となります。
==========
if(COUNTIFS(A1,"*樹脂ピアス*",A1,"*【K16GP】樹脂ピアス*"),"樹脂ピアス","")
==========

&でつないでいただき、下記のとおりとしていただくことで
「樹脂ピアス」は「樹脂ピアス」
「【K16GP】樹脂ピアス」は「【K16GP】樹脂ピアス」
と表示することができるようになります。
==========
=if(COUNTIFS(A1,"*樹脂ピアス*",A1,"*【K16GP】樹脂ピアス*"),"樹脂ピアス","")&if(countif(A1,"*【K16GP】樹脂ピアス*"),"【K16GP】樹脂ピアス","")
==========

こちらの要領で、その他の条件も追加していただきますよう、お願いいたします。

ご不明な点がございましたら、ご質問くださいませ。

Answer

ありがとうございますヽ(´ω｀*)人(*´ω｀)ﾉ私でも理解出来ました～(n*´ω`*n)♪
少しやってみて、うまくいったら解決とさせて頂きますね♪
うまくいかなかったら、もっかいここに聞きにきますｗ

丁寧に教えて頂きありがとうございました＼(^O^*)／♪

Answer

ちゃんと出来ました∩^ω^∩♪

少し違う話なのですが
同じ名前のものの個数を合計で集計したい時も、COUNTIFであっていますでしょうか？

みかん(=A2) 1個(=B2)
りんご(=A3) 5個(=B3)
バナナ(=A4) 2個(=B4)
きゅうり(=A5) 4個(=B5)
りんご(=A6) 5個(=B6)
きゅうり(=A7) 4個(=B7)
きゅうり(=A8) 4個(=B8)
みかん(=A9) 1個(=B9)

を

みかん 2個
りんご 10個
バナナ 2個
きゅうり 12個

と、纏めたいのですが
セルに数式を入力した状態では、カウント出来ないでしょうか？
色々検索してやってみたのですが
うまくいかないので
やり方あったら教えて頂きたいです！

Answer

ECマスターズの伊藤です。

> ちゃんと出来ました∩^ω^∩♪

無事、ご希望の設定ができたようで、安心いたしました。


> 同じ名前のものの個数を合計で集計したい時も、COUNTIFであっていますでしょうか？

こちらの条件の場合は、SUMIF関数をご利用いただくようなります。
＝＝＝＝＝＝＝＝＝＝
=sumif(検索したいセルの範囲,検索条件,合計したいセルの範囲)
＝＝＝＝＝＝＝＝＝＝

頂いている表のりんごの場合
ーーーーーーーーーー
検索したいセルの範囲　→　A2〜A9
検索条件　→　りんご
合計したいセルの範囲　→　B2〜B9
ーーーーーーーーーー
となりますので
＝＝＝＝＝＝＝＝＝＝
=sumif(A2:A9,"りんご",B2:B9)
＝＝＝＝＝＝＝＝＝＝
を入力いただければ、合計を表示していただくことができます。

Answer

例のA2っていうのが、

=VLOOKUP(I2,商品管理番号!$A$2:$B$442,2,0)&" / "&R2
(R2＝=IF(COUNTIFS(貼り付け!P23,"*樹脂ピアス*",貼り付け!P23,"*【K16GP】樹脂ピアス*"),"樹脂ピアス","")
&IF(COUNTIF(貼り付け!P23,"*【K16GP】樹脂ピアス*"),"【K16GP】樹脂ピアス","")
&IF(COUNTIF(貼り付け!P23,"*キーホルダー*"),"キーホルダー","")
&IF(COUNTIF(貼り付け!P23,"*合金ピアス*"),"合金ピアス","")
&IF(COUNTIF(貼り付け!P23,"*ネジ式イヤリング*"),"ネジ","")
&IF(COUNTIF(貼り付け!P23,"*クリップ式イヤリング*"),"クリップ","")
&IF(COUNTIF(貼り付け!P23,"*ネックレス*"),"ネックレス","")
&IF(COUNTIF(貼り付け!P23,"*ノンホール*"),"ノンホール樹脂","")
&IF(COUNTIF(貼り付け!P23,"*チタン*"),"チタン","")
&IF(COUNTIF(貼り付け!P23,"*【K16GP】ピアス*"),"【K16GP】ピアス","")
&IF(COUNTIF(貼り付け!P23,"*【K16GP】クリップ式イヤリング*"),"【K16GP】クリップ","")
&IF(COUNTIF(貼り付け!P23,"*【K16GP】ネジ式イヤリング*"),"ネジ","")
&IF(COUNTIF(貼り付け!P23,"*バックチャーム*"),"バックチャーム","")
&IF(COUNTIF(貼り付け!P23,"*ストラップ*"),"ストラップ","")
&IF(COUNTIF(貼り付け!P23,"*イヤーカフ*"),"イヤーカフ","")
&IF(COUNTIF(貼り付け!P23,"*【K14GF】ピアス*"),"【K14GF】ピアス",""))

になるのですが
この場合は、反応しますか？？

Answer

ECマスターズの伊藤です。

> この場合は、反応しますか？？

A2を簡単な関数にして確認したところ、問題なく表示されましたので、ご利用いただけると思います。

もし、うまくいかないようでしたら、ご相談くださいませ。

Answer

ありがとうございます☆
やってみようとしたら、1つ問題が

=sumif(A2:A9,"りんご",B2:B9)
の、"りんご"の部分なのですが、

全商品200種類で
みかん(=A2) 1個(=B2)
りんご(=A3) 5個(=B3)
バナナ(=A4) 2個(=B4)
きゅうり(=A5) 4個(=B5)
りんご(=A6) 5個(=B6)
きゅうり(=A7) 4個(=B7)
きゅうり(=A8) 4個(=B8)
みかん(=A9) 1個(=B9)

だけの受注があった場合
受注のあった

みかん
りんご
バナナ
きゅうり

の項目を自動で拾って欲しいのですが

sumifだと名前を指定しなくてはいけないので
リストは200項目になってしまいますか？？
他に何か良い方法はありますか？

Answer

ECマスターズの村井です。

休み明け担当よりご案内させていただきますので、今しばらくお待ちくださいませ。

Answer

ECマスターズの田中です。

> sumifだと名前を指定しなくてはいけないので
> リストは200項目になってしまいますか？？

sumif関数を利用した方法ですと、確かにリストは200項目になります。

> 他に何か良い方法はありますか？

ピボットテーブルをご利用いただくのはいかがでしょうか。
https://www.forguncy.com/blog/20171110_pivottable
行に商品名を、値に個数をご登録いただくことで
簡単に集計を行うことができます。

ピボットテーブルをご利用される場合、
行を追加しても自動で集計は行われませんので、
行を追加するたびに更新を行っていただきますようお願いします。
https://support.office.com/ja-jp/article/6d24cece-a038-468a-8176-8b6568ca9be2

Answer

ありがとうございます☆
ピポットテーブル、使えそうです！⁽⁽ ◟(∗ ˊωˋ ∗)◞ ⁾⁾

次は、色選択の抜き出し方法なのですが、
色名が、商品数の数だけ出来てしまい、名前指定のCOUNTIFが使えそうにありません。

・色指定:〇〇と、決まった文言を先頭に付けれます。
・〇〇=決まった文字数ではありません。
・〇〇=種類は無限です。

抜き出せる方法は無いでしょうか？

次から次にすみませんが、何か良い案ありましたらよろしくお願いします(＞人＜;)###HR######IMG0ddd792250e6362fa733c7ecf8b339b95.jpegIMG0######BR###

Answer

ECマスターズの田中です。

▲セルの中に含まれる★と◆の間の文字を取得する場合、
MID関数（開始位置と文字数を指定して、セル内の文字を抜き出す）と
FIND関数（セルの中で、指定した文字の位置を調べる）と
LEN関数（指定文字列の文字数を調べる）を組み合わせて、

=MID(▲,FIND("★",▲)+LEN("★"),FIND(◆,▲,FIND("★",▲)+LEN("★"))-FIND("★",▲)-LEN("★"))

という関数を組むことで、取得することができます。
セル内の改行は CHAR(10) という関数で取得することができますので、

たとえば、P2セルに含まれる「色選択:」の右の文字列を抜き出す場合、

=MID(P2,FIND("色選択:",P2)+LEN("色選択:"),FIND(CHAR(10),P2,FIND("色選択:",P2)+LEN("色選択:"))-FIND("色選択:",P2)-LEN("色選択:"))

という関数を組むことで抜き出すことができます。
（指定した文字がセル内に無い場合、エラーになりますのでご注意ください）

まずは、pyonさんにて関数を作成して、抜き出しをお試しいただきますようお願いします。

Answer

田中さん★

おおおお！！すごい！！抜き出せました！！
ありがとうございます！

指定した文字がセル内に無い場合、空白にしたかったら、
IFを組み合わせたら良いのかな・・と思い、やってみようとしたのですが
良くわからなくなってしまい・・・・

どう書けばいいでしょうか(´;ω;｀)

Answer

ECマスターズの田中です。

IFERROR関数を利用することで、
エラー時に空白を表示させることができます。
http://www.excel-list.com/iferror.html

私からご案内差し上げた関数を、
IFERROR(
と
,"")
で囲んでいただきますようお願いします。

Answer

ありがとうございます☆

やってみたら、そのまま数式が表示されてしまったのですが、
始めと閉じ部分は、こういう事で合っていますか？>

Answer

ECマスターズの伊藤です。

> やってみたら、そのまま数式が表示されてしまったのですが、
> 始めと閉じ部分は、こういう事で合っていますか？><

エクセルの関数は、　=　で始めることで関数と認識します。
始めの部分の記述を、下記の通り修正していただけますでしょうか。

＝＝＝＝＝修正前＝＝＝＝＝
IFERROR(=MID(P2
＝＝＝＝＝＝＝＝＝＝＝＝＝
↓↓
＝＝＝＝＝修正後＝＝＝＝＝
=IFERROR(MID(P2
＝＝＝＝＝＝＝＝＝＝＝＝＝

Answer

ありがとうございます！

そのまま何も考えずにコピペしてました(´;ω;｀)ｗ
出来ました！

話戻るのですが、
ピポットテーブルは、
=MID(▲,FIND("★",▲)+LEN("★"),FIND(◆,▲,FIND("★",▲)+LEN("★"))-FIND("★",▲)-LEN("★"))
この数式で表示させた文字は認識してくれないでしょうか？

んー・・・
先日からご指導頂き、
抜き出せたこの項目(=IFERROR(VLOOKUP(I2,商品管理番号!$A$2:$B$442,2,0)&" / "&R2&" / "&S2,"")
※R2＝=IF(COUNTIFS(貼り付け!P2,"*樹脂ピアス*",貼り付け!P2,"*【K16GP】樹脂ピアス*"),"樹脂ピアス","")
&IF(COUNTIF(貼り付け!P2,"*【K16GP】樹脂ピアス*"),"【K16GP】樹脂ピアス","")......
S2＝=IFERROR(MID(P2,FIND("色選択:",P2)+LEN("色選択:"),FIND(CHAR(10),P2,FIND("色選択:",P2)+LEN("色選択:"))-FIND("色選択:",P2)-LEN("色選択:")),""))×種類別のまとめ個数のリストを制作したいのですが可能ですか？

1）受注csvを楽天からダウンロード
2）自作エクセルに貼り付けると
3）制作リスト自動制作(その他ラベルリスト等も同時に自動制作)
としたいのですが、色項目が決まった文言で無い以上、やはり目視しか無いでしょうか？(;´Д｀)###HR######IMG055200aa68af738de10629bafde3708b0.jpegIMG0######BR###

Answer

ECマスターズの伊藤です。

> ピポットテーブルは、
> =MID(▲,FIND("★",▲)+LEN("★"),FIND(◆,▲,FIND("★",▲)+LEN("★"))-FIND("★",▲)-LEN("★"))
> この数式で表示させた文字は認識してくれないでしょうか？

こちらの関数で試したところ、問題なく認識することができました。

R列にパーツの種類
S列に色
に加え、例えば、T列に個数の列があれば、

R列、S列、T列をすべて選択→ピボットテーブル作成

列に色、行にパーツの種類、合計に個数
としていただくことで、ご希望の結果にはなりませんでしょうか。

Answer

やってみたのですが、
表の表示項目に、色選択の項目(MID)が出なくて、
商品名の所に＆を使ってMID列を組み込んだのですが、それも表示されず、
(商品名=IFERROR(VLOOKUP(I2,商品管理番号!$A$2:$B$442,2,0)&" / "&項目選択(ピアス等)列&" / "&MID色選択,"")

ピポットテーブル範囲は、
Q～Uまで指定しているのですが間のS列の項目だけ表示されなくて・・・＞＜

Q商品名
R項目選択肢
S色選択
T個数
U氏名###HR######IMG014a44566d824fe456bd40165b53516ff.jpegIMG0######BR###

Answer

ECマスターズの伊藤です。

> Q～Uまで指定しているのですが間のS列の項目だけ表示されなくて・・・＞＜

下記の関数で、問題なく表示されておりますので、
S列の関数を、下記のものに差し替えていただき、
再度ピボットテーブルの作成をお試しいただけますでしょうか。

＝＝＝＝＝＝＝＝＝＝
=IFERROR(MID(P2,FIND("色選択:",P2)+LEN("色選択:"),FIND(CHAR(10),P2,FIND("色選択:",P2)+LEN("色選択:"))-FIND("色選択:",P2)-LEN("色選択:")),"")
＝＝＝＝＝＝＝＝＝＝

Answer

ありがとうございます！

頂いた数式をコピペしたのですが、やはり同じように
S列の項目が無く、商品名も
=IFERROR(VLOOKUP(I2,商品管理番号!$A$2:$B$442,2,0)&" / "&項目選択(ピアス等)列&" / "&MID色選択
では無く
=IFERROR(VLOOKUP(I2,商品管理番号!$A$2:$B$442,2,0)&" / "&項目選択(ピアス等)列
の状態で表示されます。

Answer

ECマスターズの伊藤です。

> S列の項目が無く、商品名も
> =IFERROR(VLOOKUP(I2,商品管理番号!$A$2:$B$442,2,0)&" / "&項目選択(ピアス等)列&" / "&MID色選択
> では無く
> =IFERROR(VLOOKUP(I2,商品管理番号!$A$2:$B$442,2,0)&" / "&項目選択(ピアス等)列
> の状態で表示されます。

ご確認いただきまして、ありがとうございます。

数式コピペ後、ピボットテーブルの更新は行っていただきましたでしょうか。
ピボットテーブルは、データ修正後、自動反映されませんので、都度更新が必要となります。

ピボットテーブルの更新方法は、下記サイトにてご確認下さい。
https://www.hello-pc.net/howto-excel/pivot_failure/#s02

Answer

はい！新しくピポットテーブルを作り直した結果が、同じようになりました>

Answer

ECマスターズの伊藤です。

> はい！新しくピポットテーブルを作り直した結果が、同じようになりました><

ご確認いただきましてありがとうございます。

では、一度、作成されたエクセルを確認させていただきたいと思います。
お手数ですが、個人情報が含まれた部分は削除いただき、
club@ec-masters.net
あてにメールでお送りいただけますでしょうか。

Answer

ファイル送らせて頂きましたので、よろしくお願いいたします＞＜！

Answer

ECマスターズの田中です。

ファイルをお送りいただき、ありがとうございます。

いただいたファイルの「制作リスト」シートが、
今回ご相談いただいたS列の項目が表示されないピボットテーブルだと思うのですが、
私にて、「制作リスト」シートのピボットテーブル上で右クリック→「更新」を行ったところ、
添付画像のとおり、問題なくS列の項目が表示されるようになりました。

pyonさんでも一度、
ピボットテーブル上で右クリック→「更新」を
お試しいただきますようお願いします。
https://ec-masters.gyazo.com/48d7835c899bb4b977f9427b7394ee83

伊藤よりご案内差し上げた
https://www.hello-pc.net/howto-excel/pivot_failure/#s02
上記ページにございます通り、
データ修正後の「更新」は必ず行っていただくようお願いします。
また、同ページで紹介されている「元データをテーブルに変換」も、
データ範囲の更新漏れを防ぐ目的でオススメです。###HR######IMG0980982e60c683872591dd4109851e356.pngIMG0######BR###

Answer

あ！出ました！
すみません＞＜新規で作れば更新もされるものと思っていました(´;ω;｀)
ありがとうございます！テーブルにも変えてみます！

本当に沢山、ありがとうございました(´;ω;｀)☆
またわからなくなったら聞きにきます♪よろしくお願いします☆

Answer

ご無沙汰しておりますm(_ _)m
ピポットテーブルなのですが、
こちらのデータの集計が、###HR######IMG08158584d16b4dadb1a3618d8a94b48c8.jpegIMG0######BR###

Answer

0個になっちゃうんですが、何故でしょうか？？
更新押しました！★###HR######IMG0b9e1a9602a31a7b0063a45e26539c8b5.jpegIMG0######BR###

Answer

ECマスターズの小野です。

いただいたご質問ですが、
明日以降担当より回答させていただきますので、
少々お待ちいただければと思います。

Answer

ECマスターズの伊藤です。

> ピポットテーブルなのですが、
> こちらのデータの集計が、
> 0個になっちゃうんですが、何故でしょうか？？

恐れ入りますが、実際のデータを拝見させていただきたいので

club@ec-masters.net

宛に、EXCELデータを添付いただけますでしょうか。

その際、個人情報に当たる部分は、削除いただけますと幸いです。

どうぞよろしくお願いいたします。

Answer

送りました☆
よろしくお願いいたします！★

Answer

ECマスターズの伊藤です。

データのご連絡ありがとうございました。

確認させていただいたところ、
「貼り付け」シートの「O列」のデータが
文字列となっていました。

そのため、計算をする際に、数値として認識されず
0と表示されてしまっていました。

「O列」のデータを数値になおしていただきますよう
お願いいたします。

Answer

伊藤さんこんにちわ☆遅くなりました＞＜

O列なのですが、
「貼り付け」の色無し部分に、楽天の受注ｃｓｖデータをコピーして貼り付けています。
O列を全て打ち直すという作業を短縮したいのですが
何か良い方法はないでしょうか？

よろしくお願いいたします。

Answer

ECマスターズの伊藤です。

> O列を全て打ち直すという作業を短縮したいのですが
> 何か良い方法はないでしょうか？

VALUE関数を使用していただきますと、
文字列を数値に変換することができますので
お試しいただけますでしょうか。

貼り付けシートのT列、個数の関数を
下記の通りに修正していだきますよう、お願いいたします。

=O2
↓↓↓
=VALUE(O2)

Answer

おお！出来ました∩^ω^∩
ありがとうございます♪

またおかしくなったら来ます(;´Д｀)
長々とすみません(´;ω;｀)

Answer

お世話になっております☆

Aさん　りんご
Aさん　みかん
Bさん　りんご
Bさん　きゅうり
Bさん　きゃべつ
Cさん　いちご
Dさん　りんご
Dさん　みかん
Dさん　いちご
Dさん　きゅうり

となっているデータを

Aさん　りんご
　　　　みかん
Bさん　りんご
　　　　きゅうり
　　　　きゃべつ
Cさん　いちご
Dさん　りんご
　　　　みかん
　　　　いちご
　　　　きゅうり

としたいのですが、方法はありますか？？
よろしくお願いいたします！

Answer

ECマスターズの中野です。

以前、他の会員の方から似たご質問をいただき、
重複しているキーワードを省く変換器をご用意いたしました。
以下よりお読みいただき一度ご利用いただければと思います。
https://forum.ec-masters.net/post_view.php?id=11973

もし、こちらの内容とは別の作業についての場合は、
再度お知らせいただければと思います。

よろしくお願いいたします。

Answer

中野さんありがとうございます☆

やりたい事と、違いました〜><
名前がA列
商品名がB列で

Aさん Bさん Cさん Dさん 誰が何行使うかはランダムで

同じ人が複数購入の場合名前が連続するのですが、
複数購入だとすぐわかるようにしたいので、同じ人は1行目だけ表示 としたかったです☆

貼り付け用シートにcsvデータを貼り付けたら
梱包用シートに自動で反映するようにしたいので
よろしくお願いします！

Answer

ECマスターズの中野です。

早速ご確認いただきましてありがとうございます。

> 名前がA列
> 商品名がB列で

> Aさん Bさん Cさん Dさん 誰が何行使うかはランダムで

> 同じ人が複数購入の場合名前が連続するのですが、
> 複数購入だとすぐわかるようにしたいので、同じ人は1行目だけ表示 としたかったです☆

作業目的を詳しくご教示いただきありがとうございます。
担当の者にお伝えして、再度確認させていただき週明けに改めて回答させていただきます。

お時間いただきますがお待ちいただければと思います。
よろしくお願いいたします。

Answer

ECマスターズの田中です。

> 同じ人が複数購入の場合名前が連続するのですが、
> 複数購入だとすぐわかるようにしたいので、同じ人は1行目だけ表示 としたかったです☆

見た目だけを変更されるのでしたら、
条件付き書式をご利用いただいてはいかがでしょうか。

条件付き書式の使い方は、下記ページをご参照ください。
https://dekiru.net/article/17631/

ページ通り、「数式を使用して……」の方法を利用して、
たとえば、名前のデータがA2セルから始まる場合は、
A2セルから下を選択して、
=A1=A2
と条件を指定し、文字色を白（背景と同じ色）に設定することで
見た目上、重複する名前が見えなくなります。

あくまでも見えなくなるだけで、データとしては存在しますので、
他の表に貼り付ける場合などはご注意ください。

Answer

中野さん＞お休み中？？にありがとうございました♪

田中さんありがとうございます☆
おおおお！！って声出ました～！ｗ
やりたい事が出来ました！ありがとうございます☆

あともう一つ、
=VALUE()を使って文字列を数字に変えているセルに
=IF(COUNTIF
で1以下の場合非表示にしたかったのですが、うまくいかず
出来ないでしょうか？？
・もしできるなら、書き方がおかしかったと思うので正しい表記を教えてください
・できない場合、他の良い方法を教えてください。

よろしくお願いいたします！

Answer

ECマスターズの田中です。

たとえば、A列に =VALUE() で設定した値が並んでおり、
条件付き書式で「重複していない」値を非表示にしたい、
ということでしたら、
A2以下のセルを選択した状態で
=COUNTIF(A:A,A2)=1
とご記載いただく形になります。

もし、ご希望どおりの動作にならない場合は、
重複していない値で間違いないのか、
書式を変えたいのか、もしくはデータ自体を空白にしたいのか、
など、ご希望の動作を詳しくお知らせいただきますようお願いします。

Answer

田中さんありがとうございます☆

=VALUE(O1)
と書いていたらO1が未入力の場合、0と表示されるのを見えなくしたいので
非表示でもデータを空白でもどちらでも良いです！

=VALUE()を入れている列がT列だったので
条件式書式で
[数式を使用して・・・]のルールで
=COUNTIF(T:T,T2)=1
と入れてみたのですが
0が表示されたままでした。

O列にｃｓｖで貼り付けた、注文個数
T列にそれを拾ってきた文字列になった数字
が入っています！
T列に入る数字は(1～未確定)です☆

よろしくお願いします☆

Answer

ECマスターズの田中です。

> =VALUE(O1)
> と書いていたらO1が未入力の場合、0と表示されるのを見えなくしたい

ということですね。

「COUNTIFで1以下の場合非表示」というのは、
つまり「重複していない値を削除する」という意味になりますので、
T列で１個しか出ていない値（たとえば、58 など極端に多い数など）が
非表示になってしまいます。

ご希望どおりに動作させる場合は、

=IF(ISBLANK(O1),"",VALUE(O1))

つまり、O1に何も書かれていない場合は空白にし、
そうでなければVALUE(O1)の値を表示する、
という数式をご記載いただきますようお願いします。

なお、返信にて「＝VALUE(O1)」といただきましたので
O1を基準としておりますが、
O1に項目名が入っているなどで2行目以降に記載される場合は、
たとえばT2セルに =IF(ISBLANK(O2),"",VALUE(O2)) と記載する、
という形で、行番号を合わせて、ズレることの無いようご注意ください。

Answer

こんにちは！
すみません、作ったエクセルファイルを編集したいのですが、
追加でこのように足すと###HR######IMG03815d72a07ef251554cdc81ca9fdd899.jpegIMG0######BR###

Answer

こうなってしまうのは
何故でしょうか>

Answer

=IF(COUNTIF(貼り付け!P10,"*ラッピング:無し*"),"-","")
&IF(COUNTIF(貼り付け!P10,"*ラッピング:有り*"),"有り","")

を

=IF(COUNTIF(貼り付け!P10,"*ラッピング:無し*"),"-","")
&IF(COUNTIF(貼り付け!P10,"*ラッピング:有り*"),"有り","")
&IF(COUNTIF(貼り付け!P10,"*全て別々*"),"(別)","")

に変えました！！

Answer

ECマスターズの中野です。

>  pyonさん

いただいたこちらの内容ですが、
担当の者が週明けに確認して再度回答させていただきます。

お時間いただいておりますがお待ちいただければと思います。
よろしくお願いいたします。

Answer

ECマスターズの田中です。

「#REF!」と表示されているということは、関数に記載されたセル、
つまり「貼り付け」シートのP10セルが見つからない、
ということのようですが、
編集中のブックに「貼り付け」シートはございますでしょうか。
名前を変更などされていないでしょうか。

Answer

写真に添付したシートが、「貼り付け」シートで、
このファイルを作った時は、エクセル2009？？だったかぐらいの昔のエクセルで作っており、
先月からエクセル2019に買い替えて、元のファイルの関数や数式は引き継がれ、元ファイルも問題なく利用できると、マイクロソフトの方に案内されたのですが、
セルを編集するとセルに記入した関数がそのまま表示されたり、#REF!と表示される事と、何か関係ありますか？？？

Answer

ECマスターズの田中です。

よほどの稀なケースでない限り、
マイクロソフトの方がおっしゃるとおり、
問題なくご利用いただけるはずです。

原因を詳しくお調べする必要がございますので、
実際に作成していただいたExcelファイルを
club@ec-masters.net 宛に
お送りいただけますでしょうか。

Answer

ありがとうございます☆
ファイル、コメント挿入して送りました★
よろしくお願いいたします☆

Answer

ECマスターズの田中です。

お送りいただきありがとうございます。

いただいたファイルを確認したところ、
#REF!
となっているセルはございませんでした。

関数がそのまま表示されているのは、
セルの表示形式が「標準」ではなく「文字列」になっていることが原因です。
表示形式が「文字列」になっている場合、
セル内に数字や日付、関数が記載されても、そのまま表示するようになっております。
（商品管理番号や電話番号のように、勝手に内容を変更されたくない時に便利です）

また、Z列の関数を編集すると、
完了後に表示形式が自動で「文字列」に変更される現象も確認いたしました。
参照元のQ列のセルが表示形式「文字列」のため、自動で設定されるようです。

Q列の内容がExcelによって自動で変更されるケースもほとんどないかと思いますので、
Q列全体とZ列全体の表示形式を「標準」にご変更いただくことで、
関数がそのまま表示されるケースは解決できるかと思います。
https://www.jpita.or.jp/simin/index.php?excelziten4


「#REF!」については、数式に記載するセルの行番号が誤っている可能性がございます。

たとえば、Z5セルに
=IF(COUNTIF(貼り付け!P3,"*ラッピング:無し*"),"-","")
と記載して、Z5セルをコピーしてZ1~Z4セルに貼り付けると、
Z2セルが「#REF!」の表示になり、関数が
=IF(COUNTIF(#REF!,"*ラッピング:無し*"),"-","")
という記載になっているかと思います。

Excelには、関数を他のセルにコピーすると、
関数で使われているセルの位置も合わせてずらしてくれる機能があるのですが、
（これを「相対参照」と言います。参考：https://simin.jpita.jp/index.php?excelziten612）
上記の例の場合、5行目の関数で3行目のセルを引用しているため、
それを上にずらしていくと、
4行目の関数で2行目のセルを引用
3行目の関数で1行目のセル（つまり項目名）を引用
となり、2行目では引用するセルが見つからないため、#REF!というエラー表示になってしまいます。

このようなケースは、Excelの関数をExcel外（メモ帳など）で編集して書き戻す時、
コピー元とは別のセルに貼り付けることで発生し、
エラーが表示されない場合でも、データがズレるトラブルにつながってしまいます。

#REF!の表示がされた場合は、データのズレがないかどうか、
列全体を見直していただきますようお願いいたします。
（今回の「貼り付け」シートZ列には、ズレはございませんでしたのでご安心ください）

また、計算に使っているセルを右クリックから「削除」した場合も
#REF!が表示され、データのズレが発生するおそれがございます。
そのパターンについて解説しているページがございますので、下記ご参照ください。
https://excel-microsoft.info/%E6%95%B0%E5%BC%8F%E3%83%BB%E8%A8%88%E7%AE%97/236

Answer

ありがとうございます☆
リンクも確認し、同じ場所を「標準」にしてみたのですが、やはり同じくそのまま関数が表示されてしまいました＞＜

#REF!と出ていた時は、ひとつを編集してコピーの＋マークでドラックした時になりました。
今回は、引っ張ってみましたが#REF!ではなく、関数の文字列表示がコピーされました＞＜

Answer

ECマスターズの田中です。

> 同じ場所を「標準」にしてみたのですが、やはり同じくそのまま関数が表示されてしまいました＞＜

> 今回は、引っ張ってみましたが#REF!ではなく、関数の文字列表示がコピーされました＞＜

表示形式「文字列」のセルに記載された関数は、
表示形式を「標準」に変更しただけでは表示が変わりません。

セルをWクリック→Enterキー、つまり、編集モードにして何も変えずに確定することで、
関数を計算した結果を表示させることができます。

なお、その時、参照しているセルの表示形式が「文字列」ですと、
つられて関数のセルの表示形式も再び「文字列」に変わってしまいます。
この状態で再度関数を編集すると、また関数自体が表示されてしまいますので
ご注意ください。

> #REF!と出ていた時は、ひとつを編集してコピーの＋マークでドラックした時になりました。

現在は #REF! がなくなっているので、推測するしかないのですが、
「ひとつを編集」の際に、行番号のズレが起こっていた可能性がございます。
今後起こらないようにご注意いただければ幸いです。

Answer

おおお！できました！！
ありがとうございます(　；∀；)
ズレていたのも了解しました★

たまーに謎に成功していたので、バグってるのかな、と思い、
立ち上げ時に試してみる←を、1か月ぐらい試してました・・・ｗ

田中さん♪ありがとうございました♪ヽ(´ω｀*)人(*´ω｀)ﾉ

Answer

お世話になっております。
前回作成した受注シートを、新しいcsvで作り直そうとして、
ちゃんと表示されていた前のシートの
=IF(COUNTIFS(AD2,"*樹脂ピアス*",AD2,"*【K16GP】樹脂ピアス*"),"樹脂ピアス","")
&IF(COUNTIF(AD2,"*【K16GP】樹脂ピアス*"),"【K16GP】樹脂ピアス","")
&IF(COUNTIF(AD2,"*キーホルダー*"),"キーホルダー","")
&IF(COUNTIF(AD2,"*合金ピアス*"),"合金ピアス","")
&IF(COUNTIF(AD2,"*ネジ式イヤリング*"),"ネジ","")
&IF(COUNTIF(AD2,"*クリップ式イヤリング*"),"クリップ","")
&IF(COUNTIF(AD2,"*ネックレス*"),"ネックレス","")
&IF(COUNTIF(AD2,"*合金リング*"),"リング","")
&IF(COUNTIF(AD2,"*ノンホール*"),"ノンホール樹脂","")
&IF(COUNTIF(AD2,"*チタン*"),"チタン","")
&IF(COUNTIF(AD2,"*【K16GP】ピアス*"),"【K16GP】ピアス","")
&IF(COUNTIF(AD2,"*【K16GP】クリップ式イヤリング*"),"【K16GP】クリップ","")
&IF(COUNTIF(AD2,"*【K16GP】ネジ式イヤリング*"),"【K16GP】ネジ","")
&IF(COUNTIF(AD2,"*バックチャーム*"),"バックチャーム","")
&IF(COUNTIF(AD2,"*ストラップ*"),"ストラップ","")
&IF(COUNTIF(AD2,"*イヤーカフ*"),"イヤーカフ","")
&IF(COUNTIF(AD2,"*【K14GF】ピアス*"),"【K16GF】ピアス","")
の部分を新しいシートにそのままコピーして貼り付け、AD2の部分を任意のセル指定に編集したのですが、数式がそのまま表示され、
文字列とか標準とか触ってみたのですがちゃんと表示されず・・・
どこが間違っているのか教えて頂けないでしょうか？

よろしくお願いいたします。

Answer

ECマスターズの伊藤です。

ご回答おまたせして申し訳ありません。

> 文字列とか標準とか触ってみたのですがちゃんと表示されず・・・
> どこが間違っているのか教えて頂けないでしょうか？

数式的には間違いなさそうですので、
セルの設定が、関数が認識されない設定に
なってしまったのだと思います。

何も触ってないセルをコピー
↓
数式を入れたいセルにペースト
（セルの設定が初期化されます）
↓
元の数式の入ってるセルをダブルクリック ＞ コピー
↓
数式を入れたいセルをダブルクリック ＞ ペースト

をお試しいただけますでしょうか。

Answer

伊藤さん★

ありがとうございますヽ(´ω｀*)人(*´ω｀)ﾉ
言われた通りやったら出来ましたヽ(´ω｀*)人(*´ω｀)ﾉ♪
今カスタム頑張っているので、また詰まったらお願いします！

Answer

こんばんわ！
エクセルの質問よろしくお願いします！

ああああ いい ううううう え おお
このように半角の空白で区切った文字列を

A1に1と表示されている時は
ああああ
2と表示されている時は
ああああ いい
3と表示されている時は
ああああ いい ううううう
と表示させて欲しい
みたいな事は出来ますか？？

文字数を数えて左から抜き出す方法だと、ああああ いい ううううう え おお←文字数が異なるので出来なくて、何か方法は無いでしょうか？

↓これを組み合わせるのかなぁ・・と調べてみたのですが、こんがらがってきました。

セル内の文字で区切られている単語の数を数える
https://docs.microsoft.com/ja-jp/office/troubleshoot/excel/formulas-to-count-occurrences-in-excel
セルから文字列を抜き出すには ―LEFT 関数―
https://www.crie.co.jp/chokotech/detail/119/

よろしくお願いします！

Answer

ECマスターズの田中です。

文字列がB1に入っているとすると、たとえば
=LEFT(B1,FIND("∴",SUBSTITUTE(B1," ","∴",A1))-1)
とすることで可能です。

SUBSTITUTE関数で指定した位置の半角スペースを
滅多に使わない記号に置き換え、
その記号の直前までを抜き出すことで実現しております。
利用している関数の解説などは、下記ページをご参照ください。
http://office-qa.com/Excel/ex258.htm

このような仕組みのため、万が一
∴
という記号が文字列のどこかに出てくる可能性がある場合は、
誤動作の原因となりますので、
関数に含まれる二箇所の記号を、
また別の、使うことのない記号に差し替えてご利用願います。

Answer

田中さん★ありがとうございます！
入れてみたのですが、例のA1にどの数字が入っていても1ブロック分しか表示されません＞＜

=LEFT(画像!A2,FIND(" ",SUBSTITUTE(画像!A2," ","",マスター!S2))-1)
=LEFT(画像!A2,FIND(" ",SUBSTITUTE(画像!A2," "," ",マスター!S2))-1)

=LEFT(画像!A2,FIND("★",SUBSTITUTE(画像!A2," ","★",マスター!S2))-1)

画像!A2の空白を★に変えて書いてみても
どれもダメでした＞＜

画像!A2＝例B1
マスター!S2＝例A1

半角スペースは区切りの他に使う所が無いので、このままで大丈夫です！
どこが間違っていますか？？よろしくお願いします！

Answer

ECマスターズの田中です。

たとえば、私の環境のExcelにて
「画像」「マスター」シートを作成し、

画像シートのA2セルに
ああああ いい ううううう え おお
マスターシートのS2セルに
3

と記載し、他のセルに、いただいた
=LEFT(画像!A2,FIND("★",SUBSTITUTE(画像!A2," ","★",マスター!S2))-1)
上記関数をそのまま記載すると、
ああああ いい ううううう
と表示され、マスター!S2セルの数字を変更しても、ご希望どおり動作しているように見えます。

下記スクリーンショットも併せてご参照ください。
https://ec-masters.gyazo.com/67394f28bb347d9a9d33a1819d2efcf7

pyonさんの環境では、それでもやはり
ああああ
のみ表示される状態でしょうか。

どうしても解決できない場合は、
元質問右下の「投稿内容について報告する」より、
pyonさんにて作成いただたExcelファイルをお送りいただきますようお願いします。

Answer

田中さん★テストもありがとうございます！

あらぁ・・・何でだろう
頂いたスクショと並べてみてもおんなじなのですが・・・
ファイル送ります！今作ってる途中でぐっちゃぐちゃなので見にくくて申し訳ないですが、よろしくお願いします！###HR######IMG002cdba9273512963c0a31fc950020968.jpegIMG0###

Answer

ECマスターズの田中です。

Excelファイルをお送りいただきありがとうございます。

ファイルを確認したところ、
画像シートA2セルの区切りが★になっておりましたので、

画像シートにて
セル範囲C5:AO5をコピーして、セル範囲C4:AO4に貼り付け、
A2セルの内容を元の半角スペース区切りに戻すことで、
関数が正しく動作するようになりました。

pyonさんでも同様の操作を行っていただき、
関数が正しく動作することをご確認いただきますようお願いします。

Answer

田中さん★チェックありがとうございます★

半角空白だと感知してくれないのかな・・・と思い、区切りを★に変えてテストしてみていました☆

画像シートの区切りを半角スペースに戻して、
item.csvのオレンジの所を
=LEFT(画像!A2,FIND(" ",SUBSTITUTE(画像!A2," "," ",マスター!S2))-1)
に書き直してみたのですが、やはり1ブロック分しか私のエクセルでは表示してくれないのですが、何故でしょうか(´;ω;｀)

Answer

ECマスターズの田中です。

それではその状態で、オレンジの所の関数を
=LEFT(画像!A2,FIND("★",SUBSTITUTE(画像!A2," ","★",マスター!S2))-1)
に書き直していただくと、
正しく動作するかと思いますので、ご確認をお願いします。

関数を書き直す前に区切りを★に戻していただく必要はありません。
あくまでも、画像!A2セルは半角空白区切りのままで、
オレンジの所の関数だけを書き換えてご確認ください。

画像!A2セルに★が入っていなくても、この関数で大丈夫です。
画像!A2セルに存在しない文字を利用して、関数が動作しております。

今一度仕組みの説明になりますが、
SUBSTITUTE関数で、指定した位置の半角スペースを記号に置き換え、
その記号の直前までを抜き出すことで実現しております。
利用している関数の解説などは、下記ページをご参照ください。
http://office-qa.com/Excel/ex258.htm

Answer

ふおおおおお！！出ました！！
何故これで正しくでるのか説明読んでも全然理解できてないのですが、ちゃんと出ました！(　；∀；)！ｗ
田中さん、いつもありがとうございます＾＾♪

また詰まったら相談させてください♪
よろしくお願いします☆
ありがとうございましたヽ(´ω｀*)人(*´ω｀)ﾉ

Answer

こんにちわ！詰まりました！！(　；∀；)！よろしくお願いします！

Rたすくから、楽天のitem.csvに入っている、ディレクトリIDを
どうにかしてヤフーのスペックコードに自動で置換出来るようにしたいのですが
ヤフーのスペックコードの記述が

おそらく
アクセサリーカラー｜色:色:色
みたいなコードで
◯｜△:△:△
△は1つかもしれないし何個かもわからない
◯｜△
のみの場合もある
（おまけに入力セルも分かれてますが◯｜△の〇1種類につき1セルって感じっぽいです。同じ〇なら△複数ある場合◯｜は抜いて：で△を繋げる）

ゴールド=◯｜△
の場合もあるし
ゴールド=★｜◇
の場合もある
(アクセサリー素材｜ゴールドの場合は◯｜△、指輪素材｜ゴールドの場合は★｜◇みたいにヤフーでは親コードは全て異なるが楽天では素材ゴールドは一括した番号)

なのですが、これってエクセルじゃ、どないもならないでしょうか？(　；∀；)

Answer

ECマスターズの伊藤です。

頂いておりますご質問についてですが、
担当より、明日以降に回答させていただきます。

恐れ入りますが、ご回答まで今しばらくお待ちくださいますよう
お願いいたします。

Answer

伊藤さん★

ご連絡ありがとうございます♪今問い合わせいっぱいだろうから、落ち着いたらで大丈夫です★
よろしくお願いします！

Answer

ECマスターズの田中です。

Yahoo!ショッピングのスペックコードは
楽天市場のタグIDに相当する部分となりますが、
タグIDと異なり、同じスペックに対して複数のコードを記載する形になるため、
完全に自動にするには、VBAによるプログラミングを１から考える必要があり、
かつ、タグID→スペックコードの変換表もご用意いただく必要がございます。

完全に自動化するのではなく、
ある程度作業を進めていただき、決まったパターンがあると感じた際に、
そのパターンを自動入力できないかご検討いただく、
といった形でご対応いただく必要がございます。

Answer

田中さんありがとうございます！
VBAとは？←の部分は、こないだ入門編のYouTube見て、どんなものなのかは知っている、と言う段階です☆（まだ試してみた事は無いです！）
VBAで書く場合も、かなり複雑な指令になりますか？（　；∀；）

ハンドメイドアクセサリーで、ほぼカラー展開と金具展開があり、決まったパターンはあまり無く、かと言って200ページほど個別編集も吐きそうでこの度のシートを作りたいと思いました(´；ω；｀)

以前ストアコンバーターの有料プランで商品を一括でアップしたまんまの商品ページになっていて、大カテゴリー（ピアスやネックレス等）は置換してくれていたのだけど、色のプロダクトコード等は全て消えていました><

ある分のリストは、もう出来てます！
（◯｜△←繋げてしまいましたが分けた方が良かったらもっかい分けます！）###HR######IMG06df052e1a77f617c870466d18a1d8498.jpegIMG0###

Answer

ECマスターズの田中です。

> VBAで書く場合も、かなり複雑な指令になりますか？（　；∀；）

VBAを実際に作成いただくところから学習して組み上げるには、
複雑な指令になってしまいます。

> ある分のリストは、もう出来てます！

こちら、C列は楽天市場のディレクトリID、
D列はYahoo!ショッピングの「spec1」フィールドでしょうか。

でしたら、VLOOKUP(もしくはXLOOKUP)関数を利用して
D列の値をそのままspec1にご記載いただくことは可能です。

いただいた写真によると
宝石の種類に対してご記載いただいているようですので、
その他、色やモチーフなどの値を、
spec2以降で手入力（もしくは別途変換表を作成してVLOOKUPなど）していただく形になります。

Answer

田中さんありがとうございます★

VBA、複雑なのですね・・・
VLOOKUPを駆使したら出来そうでしょうか？？(XLOOKUPは持ってるExcelに入ってなかったです！)
同じ〇なら△複数ある場合◯｜は抜いて：で△を繋げる・・・の部分は、IFを駆使すれば何とかなりますか？？
↑
＞spec2以降で手入力（もしくは別途変換表を作成してVLOOKUPなど）していただく形になります。
それともIFじゃなくて、↑ここの説明でしょうか？？

色やモチーフなど、当店で使いそうなスペックと、楽天ディレクトリIDを繋げるリストは全て完成しています★

Answer

ECマスターズの田中です。

> 色やモチーフなど、当店で使いそうなスペックと、楽天ディレクトリIDを繋げるリストは全て完成しています★

ということであれば、
VLOOKUPで取得できるのは最初にヒットした1件のみとなりますので、
石の種類、色、モチーフ、のように、スペックの種類ごとにリストを分割して、
それぞれに対してVLOOKUPを行い、
石の種類はspec1、色はspec2、モチーフはspec3……といった形で
ご記載いただくのはいかがでしょうか。

見つからなかった部分を削除したり、同じ○のスペックをまとめるのは、
関数では難しいので、手動で作業していただく形になります。

Answer

田中さん★

ありがとうございます♪

＞石の種類はspec1、色はspec2、モチーフはspec3……といった形で
ご記載いただくのはいかがでしょうか。

ヤフーのdata.csvなのですが、
spec1は入力有り、spec2空欄、spec3入力有り・・・
と、セルが飛び飛びの入力でも問題ないでしょうか？
それだったらVLOOKUPで出来そうです＾＾♪

あと田中さんと話してたら、一気に関数で完成させるのではなくて、段階を追ってセルを分けて指示していけば何とかなりそうな気もしてきましたヽ(´ω｀*)人(*´ω｀)ﾉ♪ありがとうございます♪

Answer

田中さん★ありがとうございます♪

＞石の種類はspec1、色はspec2、モチーフはspec3……といった形で
ご記載いただくのはいかがでしょうか。

ヤフーのdata.csvなのですが、
spec1入力済、spec2空欄、spec3入力済
と、入力セルが飛び飛びになってしまってもアップロードした時に問題ないでしょうか？
それだったらVLOOKUPでいけそうです♪

田中さんと話してたら、一気に関数で完成させるんじゃなくて、段階追ってセル分けて指示していけば何とかなるような気もしてきました★ありがとうございます＾＾♪

Answer

ECマスターズの田中です。

> spec1入力済、spec2空欄、spec3入力済
> と、入力セルが飛び飛びになってしまってもアップロードした時に問題ないでしょうか？

私にて動作を確認したところ、
問題なく入力済みのスペックが反映されることがわかりました。
VLOOKUPを利用しての作成を進めていただければ幸いです。

また不明な点などございましたら、ご質問いただきますようお願いします。

Answer

こんばんわ！この度もよろしくお願いします！(休み明けのお返事で大丈夫です！)

B1に、"アピール消したい"の文言が入っている時には空白
"ポイント〇倍(個別設定から計算)"で更に貼り付けタブのAUが空白の場合は空白そして空白でない場合はVLOOKUPのもの表示
その他の文言が入っている場合はブイルックアップのもの表示

と複数の指定をしたいのですが、
＆IFですると表示がダブってしまい
入れ子にするとわけわからなくなりました。

どう書けばいいでしょうか？よろしくお願いします！###HR######IMG0a55327c56fe31fd567fa4e8eda4c2bdb.pngIMG0###

Answer

ECマスターズの田中です。

複数の条件が関係する場合は、
どうしても入れ子による処理が必要な場合がございます。

Excel2016以降でご利用いただける
IFS関数をご利用いただくと、
今回のケースでは入れ子を１段階減らすことができますので
ぜひご活用ください。
https://dekiru.net/article/14285/

入れ子の構造を考えるときは、
各関数の項目を１行ごとに分けて整理することで
構造を作りやすくなります。

今回のケースですと、私の解釈が正しければ、
おそらく下記のような構造になるはずです。

=IFS(
	B1に"アピール消したい"が入っていたら、
	空白を表示し、
	B1が"ポイント〇倍(個別設定から計算)"だったら、
	IF(
		VLOOKUPの結果が空白だったら、
		空白を表示し、そうでない場合は
		"ポイント" & VLOOKUP & "倍"を表示する。
	) という処理を行い、
	※それ以外の場合は、
	VLOOKUP の結果を表示する。
)

※の部分は、「TRUE」とすることで、それ以外の場合を実現することができます。

これを実際の関数に書き換え、１行にまとめることで、
ご希望の内容を表示させることができるようになります。

整理の際は、下記のサイトをご活用いただくと便利です。

Excel Formula Beautifier
https://www.excelformulabeautifier.com/

入力欄は複数行入力でき、上下左右に拡大することもできます。
右の選択肢を「Beautify」にして構造に間違いがないかを確認し、
「Minify」にすることで、実際にExcelに貼り付ける数式を表示し、コピーすることができます。

さらに入れ子が複雑になっていく場合、
各条件を個別に計算するためのセルを入れる作業用列を追加する方法もございます。
実際に使うデータの横に計算用のセルを追加することになるため、
予め把握していないと、一緒にコピーしてしまうなど、
作業時のミスに繋がる場合もございますので、
どうしても複雑で処理しきれない場合にご検討いただきますようお願いします。

Answer

ありがとうございます！
IFS使えました！
読みながら書いてみたのですが、これで合っていますか？

=IFS($B$1="消したい","",$B$1="ポイント〇倍(個別設定から計算)",IF(貼り付け!AU2="","",VLOOKUP($B$1,メモ!$A$2:$B$7,2,0)))

=IFS(B1が"消したい"の時は,空白,B1が"",$B$1="ポイント〇倍(個別設定から計算)"の時で,貼り付け!AU2が空白の時は,空白,それ以外はリスト参照)))
と書いてみたら、#N/Aが返ってきました！

※それ以外の場合は、
VLOOKUP の結果を表示する。をTRUEで書こうとしたら、
=IFS($B$1="消したい","",$B$1="ポイント〇倍(個別設定から計算)",IF(貼り付け!AU2="","",VLOOKUP($B$1,メモ!$A$2:$B$7,2,0),TRUE=VLOOKUP($B$1,メモ!$A$2:$B$7,2,0)))
で合ってますか？？？

Excel Formula Beautifier
ありがとうございます！
Beautifyで貼り付けてみたのですが、画像のようになりました！
下の部分が意味不明なのは、関数が間違えているからですか？
それとも私の見慣れ不足でしょうか、
見方がわかりませんでした(´;ω;｀)
Beautifyのタブの所にMinifyの文字もありませんでした！

別シートを増やして行くのでも、問題ありません！(既に2シートほど内部処理用にシート作りました(´;ω;｀)ｗ)###HR######IMG0596a9c09aabc83414d14a6a211ffb4e2.pngIMG0###

Answer

ECマスターズの田中です。

> Beautifyで貼り付けてみたのですが、画像のようになりました！

おそらく、ページの翻訳機能をご利用されているかと思います。

ブラウザの翻訳機能は、
ページの内容を直接書き換える関係から、
正確に書く必要がある関数の内容も書き換わってしまいますので、
このサイトでは極力利用をお控えいただきますようお願いします。
機能をオフにすることで、「Beautify」クリック時に「Minify」が表示されるはずです。

また、翻訳機能をオフにした状態で、Excel Formula Beautifierに

=IFS($B$1="消したい","",$B$1="ポイント〇倍(個別設定から計算)",IF(貼り付け!AU2="","",VLOOKUP($B$1,メモ!$A$2:$B$7,2,0)))

を貼り付けていただくと、
きれいな構造になっていることがおわかりいただけるかと思います。

上記の式の場合、

B1セルが「消したい」ならば、
空白を表示し、
B1セルが「ポイント〇倍(個別設定から計算)」ならば、
AU行が空白の場合に空白を、空白でなければVLOOKUPの結果を表示する。

という構造になっております。
VLOOKUPは、
行番号を問わず、B1セルの内容を「メモ」シートから検索し、B列の値を表示する、
という仕組みになっておりますが、こちらはご希望の動作で間違いないかご確認願います。

続きまして、同じくExcel Formula Beautifierに

=IFS($B$1="消したい","",$B$1="ポイント〇倍(個別設定から計算)",IF(貼り付け!AU2="","",VLOOKUP($B$1,メモ!$A$2:$B$7,2,0),TRUE=VLOOKUP($B$1,メモ!$A$2:$B$7,2,0)))

を貼り付けていただくと、
「TRUE=VLOOKUP(後略)」の部分が、
「ポイント○倍(個別設定から計算)」だった場合に動作するIF関数の中に
入ってしまっていることが、おわかりいただけるかと思います。

B1が「消したい」の場合、「ポイント〇倍(個別設定から計算)」の場合、それ以外の場合、
という判断ができるよう、

=IFS(
    $B$1 = "消したい",
    "",
    $B$1 = "ポイント〇倍(個別設定から計算)",
    IF(
			(中略)
    ),
		TRUE,
		（※B1がそれ以外である場合に表示する内容）
)

という構造になるように、数式の修正を一度お試しいただきますようお願いします。

Answer

ありがとうございます！通訳をOFFにしたら、Excel Formula Beautifierがちゃんと理解できる形で表示されました！(ギリギリですが！ｗ)

=IFS($B$1="消したい","",$B$1="ポイント〇倍(個別設定から計算)",IF(貼り付け!AU2="","",VLOOKUP($B$1,メモ!$A$2:$B$7,2,0),TRUE,VLOOKUP($B$1,メモ!$A$2:$B$7,2,0)))

こう書いてみたら、添付画像1枚目のように、

$B$1 = "ポイント〇倍(個別設定から計算)",
    IF(
↑
TRUE,は、ここの入れ子になってしまっているという事で合ってますか？？

--話が飛びますが↓--

今私がやろうとしてるのは

1）B1が「消したい」の場合＝空白
2）「ポイント〇倍(個別設定から計算)」の場合
・かつ貼り付け!AU2が空白だった場合は空白
・それ以外は(文字が入ってた場合は)VLOOKUP表示
3）それ以外の場合＝VLOOKUP表示

としようとしていたのですが、
もしかして

1）B1が「消したい」の場合＝空白
2）「消したい」以外の場合＝VLOOKUPを表示
↑※2）の入れ子で「ポイント〇倍(個別設定から計算)」の場合で、かつ貼り付け!AU2が空白だった場合は空白

ってした方が、考え方がシンプルになって良いのかな・・・と思ったのですが
書けますか？？？？？書こうとしたら余計ややこしくなってしまうでしょうか？？

そして、--話戻ります--
=IFS($B$1="消したい","",$B$1="ポイント〇倍(個別設定から計算)",IF(貼り付け!AU2="","",VLOOKUP($B$1,メモ!$A$2:$B$7,2,0),TRUE,VLOOKUP($B$1,メモ!$A$2:$B$7,2,0)))
と書いてみたら添付のようなエラーが出てしまいました(´;ω;｀)###HR######IMG08588b6054acea3d3e71a314f1fe17707.pngIMG0### ###IMG1d508139735be611cfd81382f47a00a57.pngIMG1###

Answer

ECマスターズの田中です。

> TRUE,は、ここの入れ子になってしまっているという事で合ってますか？？

はい、
B1が「ポイント〇倍(個別設定から計算)」だった場合に実行するIF関数の
中に入ってしまっております。

（前略）
		VLOOKUP(
			（中略）
		),
	),
	TRUE,
	VLOOKUP(
		（中略）
	)
)

のように、３つ目の論理式・真の場合が、
B1が「ポイント〇倍(個別設定から計算)」だった場合に実行するIF関数と
同じ高さに並ぶよう、修正していただきますようお願いします。

> 書けますか？？？？？

B1が「ポイント〇倍(個別設定から計算)」かつAU列が空白だった場合、
およびB1がそれ以外の場合に表示する「VLOOKUP表示」の内容は
まったく同じ、ということでよろしいでしょうか。
でしたら、書くことはできます。

Excel Formula Beautifierに近い表現をしますと

=IF(
	B1が"消したい"であれば
	空白を表示する、でなければ
	IF
		AND(
			B1が"ポイント〇倍(個別設定から計算)"であり、なおかつ
			貼り付け!AU2が空白である
		) ならば
		空白を表示する、でなければ
		VOOKUPの結果を表示する
	)
)

という形になります。
さらにわかりやすくするならば、
今回の表示結果をまとめると２パターンとなりますので、

=IF(
	OR(
		B1が"消したい"である、もしくは
		AND(
			B1が"ポイント〇倍(個別設定から計算)"であり、なおかつ
			貼り付け!AU2が空白である
		)
	) ならば
	空白を表示する、でなければ
	VLOOKUPの結果を表示する
)

のように条件をまとめて、１つのIF関数にまとめていただいても結構です。

Answer

田中さんありがとうございます！
一番最後の方法で書いてみました！

=IF(OR(B1="消したい",(AND(B1="ポイント〇倍(個別設定から計算)",貼り付け!AU2=""),"",VLOOKUP($B$1,メモ!$A$2:$B$7,2,0))),"",VLOOKUP($B$1,メモ!$A$2:$B$7,2,0))

こう書いたら、添付のエラーが出たのですが、どこがおかしいのか分からず、
書き方合っていますか？？

また、Excel Formula Beautifierで同じ高さに並ぶよう修正っていうのが、
結局自力で正解の式をかけなきゃ修正できなくないか？となったのですが
使い方間違ってるのでしょうか・・・もっと簡単なシステムなのでしょうか？(　；∀；)

今回だと
エクセルで書いた
=IF(OR(B1="消したい",(AND(B1="ポイント〇倍(個別設定から計算)",貼り付け!AU2=""),"",VLOOKUP($B$1,メモ!$A$2:$B$7,2,0))),"",VLOOKUP($B$1,メモ!$A$2:$B$7,2,0))
を入力BOXに入れてみて
田中さんに同じ高さになるように修正して
と言われた場合、

=IF(OR(B1="消したい",(AND(B1="ポイント〇倍(個別設定から計算)",貼り付け!AU2=""),"",VLOOKUP($B$1,メモ!$A$2:$B$7,2,0))),"",VLOOKUP($B$1,メモ!$A$2:$B$7,2,0))
↑こやつをなんとかいじくって・・・・

=IF(
    OR(
        B1 = "消したい",
        (            AND(
                B1 = "ポイント〇倍(個別設定から計算)",
                貼り付け!AU2 = ""
            ) , "" ,
            VLOOKUP(
                $B$1,
                メモ!$A$2:$B$7,
                2,
                0
            ) )
    ),
    "",
    VLOOKUP(
        $B$1,
        メモ!$A$2:$B$7,
        2,
        0
    )
)
↑これを正解に近づけていく
みたいな事を私はしていたのですが
使い方合ってますか？(　；∀；)ｗ###HR######IMG0d96e159e6ee2336192285cbc0a0e6c5c.pngIMG0###

Answer

ECマスターズの伊藤です。

頂いておりますご質問についてですが、
本日、田中がお休みを頂いておりますため、
明日以降に回答させていただきます。

恐れ入りますが、ご回答までお待ちいただきますよう
お願いいたします。

Answer

ECマスターズの田中です。

はい、使い方は合っております。
Excel Formula Beautifierは、お試しいただいたとおり、
式を貼り付けた後に試行錯誤で修正を行い、
正解に近づけているかどうかをわかりやすく確認するための
ツールとなっております。

今回ご希望の内容は、下記のようにご記載いただくことで実現できます。

=IF( OR( B1 = "消したい", AND( B1 = "ポイント〇倍(個別設定から計算)", 貼り付け!AU2 = "" ) ), "", VLOOKUP( $B$1, メモ!$A$2:$B$7, 2, 0 ) )

Excel上でご希望どおり動作するかご確認願います。

また、Excel Formula Beautifierに貼り付けていただき、
各関数の引数の内容が1行ごとに整理されている様子も
併せてご確認いただきますようお願いします。###HR######IMG033ebcbcd4eb21d602500f522635bead6.pngIMG0###

Answer

田中さんヽ(´ω｀*)人(*´ω｀)ﾉ
ありがとうございます！作動ちゃんとなりました！

=IF(OR(B1="消したい",AND(B1="ポイント〇倍(個別設定から計算)",貼り付け!AU2="")),"",VLOOKUP($B$1,メモ!$A$2:$B$7,2,0))),"",VLOOKUP($B$1,メモ!$A$2:$B$7,2,0))

こう書いたらやっぱり前回のエラーが出てしまい、田中さんが書いてくれたものをそのままコピって貼ったらエラーが出なくなりました。
ちゃんとスペースも必要なのですね＞＜
(Excel Formula Beautifierで確認してみたらちゃんと表示されていませんでした！)

今回もありがとうございました☆
無事作りたかったシートが完成しました♪

また困ったらよろしくお願いします！

Answer

ECマスターズの田中です。

関数内のスペースは、特に必要ありません。

> =IF(OR(B1="消したい",AND(B1="ポイント〇倍(個別設定から計算)",貼り付け!AU2="")),"",VLOOKUP($B$1,メモ!$A$2:$B$7,2,0))),"",VLOOKUP($B$1,メモ!$A$2:$B$7,2,0))
> こう書いたらやっぱり前回のエラーが出てしまい、

こちらの数式は、私の書いた数式と比べると、末尾に余計な
),"",VLOOKUP($B$1,メモ!$A$2:$B$7,2,0))
が記載されており、数式としての構造が崩れておりますので、
エラーが出るようになっております。

Excel Formula Beautifierでも表示できないパターンとなりますので、
次回以降数式を作成される際は、
まず数式内の ( と ) の数が一致しているかどうかをご確認いただいた上で、
Excel Formula Beautifierのチェックなどに移っていただくことをおすすめします。

Answer

田中さん☆

ありがとうございます！ちゃんと見比べきれてなかっただけでした(　；∀；)！ｗ
教えて貰った通り、正しい記述にしたらスペースが入ってても入っていなくても、エラー出なくなりましたヽ(´ω｀*)人(*´ω｀)ﾉ(スペースも無駄なもの入れてはいけないものだと思っていました！)

考え方の基本から教えて頂き、ありがとうございましたヽ(´ω｀*)人(*´ω｀)ﾉ♪

Answer

こんにちわ☆この度もお願いしますm(__)m

A
(1)ピンク
(1)-
(10)ブラウン

と入っていた場合
"(1)"の後ろに”-”以外の文字がある場合は"1"、
"(1)-"となっていた場合は"-"
"(10)"ブラウンとなっていた場合は10
(※空白の場合は空白)
と表示させたいのですがうまくいきません。

以前教えて頂いた、
IF(COUNTIFS(F2,"*-*",F2,"*(1)-*"),"*-*","")
これで出来るかなぁと試してみたのですがうまくいきませんでした＞＜
よろしくお願いします！

(前回お返事しないで終わってしまいすみませんでした！)

Answer

ECマスターズの伊藤です。

> "(1)"の後ろに”-”以外の文字がある場合は"1"、
> "(1)-"となっていた場合は"-"
> "(10)"ブラウンとなっていた場合は10
> (※空白の場合は空白)
> と表示させたいのですがうまくいきません。

頂いている条件の場合

=IF(RIGHT(A1)="-", "-", IF(A1="", "", MID(A1,FIND("(",A1)+1,FIND(")",A1)-FIND("(",A1)-1)))

にてご対応可能となります。

・一番右が"-"ならハイフンにする。
・セルが空なら空欄にする
・それ以外なら()内の数字を表示する

といった処理となっておりますので、
もし想定されている条件と異なる場合は、
ご連絡くださいませ。

Answer

伊藤さん★

ありがとうございますヽ(´ω｀*)人(*´ω｀)ﾉ
ちゃんとなりました！1～10まで入って欲しい数字が入り、-は-、空白は空白になりました♪
ちなみにこれが、

(A)ピアス
(A)-
(F)イヤリング

と入っていた場合
"(A)"の後ろに”-”以外の文字がある場合は"1"、
"(A)-"となっていた場合は"-"
"(F)"ブラウンとなっていた場合は10
(※空白の場合は空白)

だと出来ますか？？？
よろしくお願いします☆

Answer

間違えました！

(A)ピアス
(A)-
(F)イヤリング

と入っていた場合
"(A)"の後ろに”-”以外の文字がある場合は"a"、
"(A)-"となっていた場合は"-"
"(F)"ブラウンとなっていた場合はｆ
(※空白の場合は空白)

です！！

Answer

ECマスターズの伊藤です。

データの状態を確認させていただきたいのですが、

(A)ピアス
(A)-
(F)イヤリング
(1)ピンク
(1)-
(10)ブラウン

このように混在しますでしょうか？
それとも

(A)ピアス
(A)-
(F)イヤリング

のパターンのみになりますでしょうか。

ご確認をお願いいたします。

Answer

A～Fまで不定期数混在しますが、英語のみになります！(数字は混ざりません！)
serect.csvを作る時の項目選択肢別在庫の小番号を自動で割り振りたいので
金具項目(項目選択肢別在庫用縦軸)の列に(A)ピアス(B)樹脂ピアス・・・・等が順番に入り(ですが色数は不特定なので使う行数は同じではない)、選択肢が無い場合には必ず"(A)-"と入ります！

Answer

ECマスターズの伊藤です。

> A～Fまで不定期数混在しますが、英語のみになります！(数字は混ざりません！)

ご確認いただきまして、ありがとうございました。

先の情報と混在しないとのことですので、
下記関数にて、ご希望どおりの表示となるか
お試しくださいませ。

=IF(RIGHT(A1)="-", "-", IF(A1="", "", LOWER(MID(A1,FIND("(",A1)+1,FIND(")",A1)-FIND("(",A1)-1))))

Answer

伊藤さん★

ありがとうございますヽ(´ω｀*)人(*´ω｀)ﾉちゃんとなりました★
ここがバグってて子番号がおかしくなってて、SKU番号も全部バグってる事に気づき、解決する事が出来ました♪
この度もありがとうございました♪
また詰まったらよろしくお願いします☆

Answer

お久しぶりです★
ロボットインからネクストエンジンに切り替えて、また受注シートを作らなくてはいけなくなりました(；ﾟДﾟ)よろしくお願いします。

商品名/カラー/金具
に並んでいるカラーを抜き出したいのですが

=MID(L2,FIND(“/",L2)+1,FIND(“/",L2)-FIND(“/",L2)-1)

こう書いてエラーになるのは同じ文字列でどっちかわからないって事でしょうか？？
区切り線で分ける等のアクションは無しで自動で表示させたいのですが、どうすれば可能でしょうか？
よろしくお願いします。###HR######IMG0969836a020288be88d2ad19b00e28b94.pngIMG0###

Answer

すみません、きっぺさんが教えてくれて解決しましたヽ(´ω｀*)人(*´ω｀)ﾉ

=MID(L2,FIND("/",L2)+1,FIND("/",L2,FIND("/",L2)+1)-FIND("/",L2)-1)
でいけましたヽ(´ω｀*)人(*´ω｀)ﾉ♪
もし良かったら解説お願いします(｡-人-｡)

Answer

続けて質問です。
商品名/カラー/金具
の金具や商品名を抜き出したい時はどうなりますか？
よろしくお願いいたします。

Answer

あと、
AorＢと一致する管理番号がある場合Ｃ列を抜き出したいのですが、
うまく出来なかったのでそれも教えて欲しいです＞＜###HR######IMG0d564aa701a99eeb42f2063ca486220ac.pngIMG0###

Answer

ECマスターズの田中美帆です。

> 商品名/カラー/金具
> に並んでいるカラーを抜き出したいのですが

> 商品名/カラー/金具
> の金具や商品名を抜き出したい時はどうなりますか？

関数を使わず、

データ > 区切り位置

から「/」で文字列を区切る
方法はいかがでしょうか。

https://ec-masters.gyazo.com/1b2bdfc9f2d5fdec0e9d447f16e3d87d


> AorＢと一致する管理番号がある場合Ｃ列を抜き出したいのですが、
> うまく出来なかったのでそれも教えて欲しいです＞＜

一致する管理番号がセルD1に入っている
と仮定して、以下の計算式にて
A列もしくはB列がD1と一致した場合に
C列を抜き出します。

=IF(OR(A1=$D$1, B1=$D$1),C1, "")

Answer

田中さん★ありがとうございます。
一番最初に言ったように、区切り線で分ける等のアクションは無しで自動で表示させたいです★

=IF(OR(A1=$D$1, B1=$D$1),C1, "")
これだと、行が一致していないと出ないですよね？？

商品リストが別にあり、その表を参照して
AorＢと一致する管理番号がある場合Ｃ列を抜き出したいです💡

Answer

こんなに長いフォーラム初めて見ましたww


商品名/カラー/金具


商品名
=LEFT(L2,FIND("/",L2)-1)
L2の左からn文字を表示してね。
nは最初の"/"の位置を参照してね。

金具
=RIGHT(L2,FIND("/",L2,FIND("/",L2))-2)
L2の右からn文字を表示してね。
nは最初の"/"の位置より後の"/"の位置を参照してね。


お試しください！！

Answer

ECマスターズの田中美帆です。

きっぺさん、フォローいただき
誠にありがとうございます。

pyonさん

> これだと、行が一致していないと出ないですよね？？
> 商品リストが別にあり、その表を参照して
> AorＢと一致する管理番号がある場合Ｃ列を抜き出したいです

以下の計算式でいかがでしょうか。
参照する商品リストの範囲がD列と仮定します。

=IF(COUNTIF(D:D, A1) + COUNTIF(D:D, B1) > 0, C1, "")

Answer

きっぺさん＞

ありがとうございます(　；∀；)！
画像1：ズレたりズレなかったりするのは何でですか？？😂
あっちこっちに書くとわからなくなるので、Excelの質問全部ここでしていますｗ

田中さん＞

ありがとうございます、田中さんが書いてくれた関数に当てはめると(画像2)こういう意味なんですが伝わりますか？？？

一応自分で調べて

https://nyanto.jimdofree.com/%EF%BD%B4%EF%BD%B8%EF%BD%BE%EF%BE%99%E9%96%A2%E6%95%B0-%E8%AA%AC%E6%98%8E/index-match%E9%96%A2%E6%95%B0%E3%81%A7%E6%9D%A1%E4%BB%B6%E3%81%AB%E5%90%88%E3%81%A3%E3%81%9F%E8%A1%8C%E3%81%AE%E5%80%A4%E3%82%92%E6%8A%9C%E3%81%8D%E5%87%BA%E3%81%99%E5%9F%BA%E6%9C%AC%E7%9A%84%E3%81%AA%E4%BD%BF%E3%81%84%E6%96%B9/index-match%E9%96%A2%E6%95%B0%E3%81%A7%E8%A4%87%E6%95%B0%E6%9D%A1%E4%BB%B6%E3%81%ABor%E3%81%A7%E4%B8%80%E8%87%B4/

これをやってみたのですが、うまくいかなくて
どう書いたらちゃんとなるんだろうとなりまして＞＜

商品リストが例で書いたAorＢと一致する管理番号がある場合Ｃ列の文言があり
入力したいセルは別シートのD列です💡###HR######IMG0e61720d592d2f789e04f620a72983a55.pngIMG0### ###IMG167096c3d82c73d797838dd087e67ea9c.pngIMG1###

Answer

あれ？？w
very sorryです！下記ですね！！
L列に"●"が入ってないことが条件になります！！

=RIGHT(L2,LEN(L2)-FIND("●", SUBSTITUTE(L2, "/", "●", LEN(L2) - LEN(SUBSTITUTE(L2, "/", "")))))

Answer

きっぺさん＞

うおおおお！出ましたヽ(´ω｀*)人(*´ω｀)ﾉ
ありがとうございます♪
●はあそこに入れない( ..)φメモメモ###HR######IMG01415e2904a1b2501d12b77eb0ad1889f.pngIMG0###

Answer

ECマスターズの田中美帆です。

回答にお時間をいただいており
申し訳ありません。

> 田中さんが書いてくれた関数に当てはめると(画像2)こういう意味なんですが伝わりますか？？？

Excelのサンプルを添付しますので、
実現したいことがこちらで合っているか、
ご確認お願いいたします。

A列またはB列がセルDと一致する場合に、
C列の文字列を返します。

例えば、

商品名（A列）：りんご
品種　（B列）：ふじ
価格　（C列）：1000円

という商品があり、D列に
「りんご」「ふじ」どちらかを
入力すると「1000円」が返されます。

A列とB列にない文字列を入力した場合
（例えば「いちご」）は空白になります。

計算式については、以下の記事を
参考にしています。

（Excel）XLOOKUP関数で検索範囲に複数列を指定する
https://www.officeisyours.com/entry/2023/09/15/130000


本日のオンライン交流会では、
伊藤が参加できず失礼しました。

実現したいことが上記と異なる場合、
文字では共有が難しいと思いますので、
画面共有でお伺いしたいと思います。###HR######FILE08a67028745642ad490dd7032cb9cb67c.xlsxFILE0###

Answer

田中さん＞

ありがとうございます！例で挙げてもらった通りです！
A列とB列とC列が2000行ぐらいある感じです💡
この今例えてくれたやつの数式が=IF(COUNTIF(D:D, A1) + COUNTIF(D:D, B1) > 0, C1, "")でしょうか？？？

画面共有お願い出来るならお願いしたいです！
添付して頂いたサンプルファイルは保護ビューで見れませんでした＞＜

Answer

ECマスターズの田中美帆です。

> 添付して頂いたサンプルファイルは保護ビューで見れませんでした＞＜

以下の方法で解除できるかお試しください。

保護ビュー（保護されたビュー）について、編集、設定、解除（無効化）
https://www.helpforest.com/office/of_use/of010009.htm


念の為サンプルの中身を共有いたします。

https://ec-masters.gyazo.com/f5e17c68b7fe6aa5640fc1e397738cd8

上記のようなデータを作成しており、
E列に

=IFERROR(XLOOKUP(TRUE,(A:A=D2)+(B:B=D2)>0,C:C),"")

という計算式を入れています。

Answer

ありがとうございます★ファイル開けました！
=IFERROR(XLOOKUP(TRUE,(A:A=D2)+(B:B=D2)>0,C:C),"")
を入れてみたのですが、何も文言が表示されず、
サンプルファイルの関数が入ったセルも何も表示されません💡###HR######IMG09ed39fb059111ed23895b5efa3c57546.pngIMG0### ###IMG190067355df77e9dbd4b92a6e5909b940.pngIMG1###

Answer

ECマスターズの伊藤です。

> =IFERROR(XLOOKUP(TRUE,(A:A=D2)+(B:B=D2)>0,C:C),"")
> を入れてみたのですが、何も文言が表示されず、
> サンプルファイルの関数が入ったセルも何も表示されません💡

=IFERROR(XLOOKUP(TRUE,(A:A=D2)+(B:B=D2)>0,C:C),"")
の、D2が参照したい値（検索したい文字）となっています。

具体的には下記のとおりとなります。
=IFERROR(XLOOKUP(TRUE,(【検索したい範囲（列A）】=【検索したい文字】)+(【検索したい範囲（列B）】=【検索したい文字】)>0,【返したい値（列C）】),"")

そのため、D2の編集をお願い致します。

また、画面共有についてご希望であれば、
明日(26日)の13時半〜17時のあいだであれば
可能ですので、お時間をご指定ください。

Answer

伊藤さん＞

ありがとうございます☆
添付画像の通り、=IFERROR(XLOOKUP(TRUE,(【検索したい範囲（列A）】=【検索したい文字】)+(【検索したい範囲（列B）】=【検索したい文字】)>0,【返したい値（列C）】),"")に設定したので

=IFERROR(XLOOKUP(TRUE,(商品管理番号!A:A=D2)+(商品管理番号!B:B=D2)>0,商品管理番号!C:C),"")
を書いたんですが、何も表示されなく、

頂いたファイルにも何も表示されておりません

26日13時半でお願いします！

Answer

2021/05/28 18:13　で
XLOOKUP入ってないって書いてるんで
XLOOKUP追加される前のEXCELのVerっぽいですね（・▽・）

Answer

差し込みごめんなさい・・・・
sampleでいうところの下記でいかがでしょう？？？

=IFERROR(VLOOKUP(D2,A:C,3,0),IFERROR(VLOOKUP(D2,B:C,2,0),""))

Aを参照してVLOOKUPスルヨ
エラーだったらBでやってミルヨ
それでもエラーなら空白返スヨ

Answer

きっぺさん＞

ぐおおおおおおおおお出ましたぁぁぁぁあ(　；∀；)！！！！！！
楽天の商品コードでも(画像1)
ヤフーの商品コードでも(画像2)
出るようになりました(´;ω;｀)！！✨
ゴッドきっぺと呼ばせて頂きます。ｗ

伊藤さん＞

ZOOM無くても大丈夫そうになりました！☆###HR######IMG0af5380f2d6113ce1383f7dcaf9ee8a60.pngIMG0### ###IMG1ac1b6e8bca95703795b54fa12a0b083f.pngIMG1###

Answer

ECマスターズの伊藤です。

無事ご解決いただけたようでよかったです！

きっぺさん＞
ご回答にご協力いただき、ありがとうございました。

Answer

伊藤さん・きっぺさん・田中さん

ありがとうございましたヽ(´ω｀*)人(*´ω｀)ﾉ
無事ファッションザセールまでに受注シートが完成出来ました♪
またわからなくなったらよろしくお願いします♪